RPTools.net

Code: Select all

<!-- set some basic values -->
[H: saveDC = 0]
[H: tokenList = getSelected()]
[H: statNameList = "STR,DEX,CON,INT,WIS,CHR"]
[H: advantageColorCode = "black,blue,red"]
[H: output = ""]

<!-- get user input -->
[H: abort(input("saveDC|0|Enter Save DC|TEXT",
    "rollAdvantage|No Advantage,Advantage,Disadvantage|Select Advantage|RADIO|ORIENT=H",
    strformat("statName|%{statNameList}|Choose Stat Save|RADIO|VALUE=STRING"),
    "outputType|all,self,gm|Output to Who?|RADIO|SELECT=1 ORIENT=H VALUE=STRING"
))]

<!-- get token data, rolls and saving throw modifier -->
[H, foreach(tokenId,tokenList), code: {
    [H: switchToken(tokenId)]
    
    <!-- get advantage roll -->
    [H: saveRoll = 1d20]
    [H, if(rollAdvantage == 1): saveRoll = max(1d20,saveRoll)]
    [H, if(rollAdvantage == 2): saveRoll = min(1d20,saveRoll)]
    
    <!-- get token stat save roll modifier. note: token name is not case sensitive -->
    [H: statModifier = getProperty(statName+"Save")]
    
    <!-- calc total -->
    [H: rollTotal = statModifier + saveRoll]
    [H: rollColor = listGet(advantageColorCode,rollAdvantage)]
    
    <!-- set state DCFail value. Probably shouldnt do it here, but its easier -->
    [H, if(rollTotal < saveDC): state.DCFail = 1; state.DCFail = 0]
    
    <!-- save output for each token -->
    [H: output = json.append(output,strformat('%{token.name} makes a %{statName} Save and gets a <span title="Roll: %{saveRoll}; Mod: %{statModifier}"><b color="%{rollColor}">%{rollTotal}</b></span>.'))]
}]

<!-- Display Output -->
[H: broadcast(json.toList(output,"<BR>"),eval("bot_"+outputType+"()"))]

<!-- you can remove this line if you make a function of this with hidden output, or you can remove all the comments for final macro -->
[H: abort(0)]