LABEL
Erstellt eine statische Kennzeichnung und kann z. B. als Überschrift oder Hinweistext verwendet werden. Eine Variable muss zwar angegeben werden, diese wird allerdings ignoriert und es wird ihr auch kein Wert zugewiesen.
Mögliche Optionen:
TEXT=FALSE
Der Anfangswert wird nicht angezeigt. Der Standardwert ist "TEXT=TRUE".
SPAN=TRUE
Erlaubt der Kennzeichnung die Ausdehnung in die gesamte Breite des Eingabefensters. Der Titel der Kennzeichnung wird dabei versteckt und nur als Tooltip angezeigt. Der Standardwert ist "SPAN=FALSE".
Beispiel:
Code: Select all
[h: status = input(
"label1|Die erste Kennzeichnung|Titel 1|LABEL",
"label2|Die zweite Kennzeichnung|Titel 2|LABEL|TEXT=FALSE",
"label3|Die dritte Kennzeichnung|Titel 3|LABEL|SPAN=TRUE"
)]
[h: abort(status)]
PROPS
Erstellt eine umrandete Box die mehrere Textfelder enthalten kann. Der Anfangswert muss zwingend eine String Property Liste sein. Die Schlüssel der Liste sind die Titel der Textfelder, und die den Schlüsseln zugeordneten Werte sind die Anfangswerte der Textfelder. In der angegebenen Variable wird ebenfalls eine String Property Liste gespeichert, die dann die aktuellen Werte der Textfelder enthält.
Mögliche Optionen:
SETVARS=SUFFIXED
Speichert zusätzlich jeden Eintrag der String Property Liste in einer eigenen Variable. Die zusätzlichen Variablen werden nach den Schlüsseln der Liste gefolgt von einem Unterstrich (_) benannt. Der Standartwert ist "SETVARS=NONE".
Diese Option besitzt eine weitere Einstellungsmöglichkeit:
SETVARS=UNSUFFIXED
Speichert zusätzlich jeden Eintrag der String Property Liste in einer eigenen Variable. Die zusätzlichen Variablen werden nach den Schlüsseln der Liste benannt.
SPAN=TRUE
Erlaubt der Box die Ausdehnung in die gesamte Breite des Eingabefensters. Der Standardwert ist "SPAN=FALSE".
Beispiele:
Code: Select all
[h: status = input(
"props.list|Name=Schwert; Typ=Klingenwaffe; Schadensbonus=2|Waffeneditor|PROPS"
)]
[h: abort(status)]
[r: props.list]
Code: Select all
[h: status = input(
"props.list|Name=Schwert; Typ=Klingenwaffe; Schadensbonus=2|Waffeneditor|PROPS|SETVARS=SUFFIXED"
)]
[h: abort(status)]
Waffenname: [r: Name_] - Waffentyp: [r: Typ_] - Schadensbonus: [r: Schadensbonus_]
Code: Select all
[h: status = input(
"props.list|Name=Schwert; Typ=Klingenwaffe; Schadensbonus=2|Waffeneditor|PROPS|SETVARS=UNSUFFIXED"
)]
[h: abort(status)]
Waffenname: [r: Name] - Waffentyp: [r: Typ] - Schadensbonus: [r: Schadensbonus]
TAB
Erstellt im Eingabefenster ein oder mehrere Tabs (Registerreiter), die jeweils verschiedene Eingabefelder enthalten können. Hierbei müssen einige Dinge beachtet werden:
- Bei Tabs wird kein Titel angegeben.
- Alle Eingabefelder innerhalb eines Tabs werden als ein Parameter, also ein String notiert, und somit zusammen statt einzeln in doppelte Anführungszeichen eingeschlossen.
- Die Eingabefelder innerhalb eines Tabs werden nicht durch Kommata (,), sondern durch doppelte Rauten (##) voneinander getrennt.
- Zusätzlich zu den Variablen der einzelnen Eingabefelder werden in den Variablen der Tabs alle Eingabefelder innerhalb dieses Tabs als String Property Liste gespeichert. Dabei werden statt Semikolons (;) doppelte Rauten (##) als Trennzeichen verwendet.
SELECT=TRUE
Zeigt diesen Tab bei Aufruf des Eingabefensters an. Der Standardwert ist "SELECT=FALSE".
Beispiele:
Code: Select all
[h: status = input(
"tab0 | Waffe || TAB",
"waffe.name|Bitte eingeben|Name|TEXT ##
waffe.typ|Bitte eingeben|Typ|TEXT ##
waffe.bonus|Bitte eingeben|Schadensbonus|TEXT",
"tab1 | Inventar || TAB",
"item1|Bitte eingeben|Gegenstand 1|TEXT ##
item2|Bitte eingeben|Gegenstand 2|TEXT ##
item3|Bitte eingeben|Gegenstand 3|TEXT"
)]
[h: abort(status)]
Waffenname: [r: waffe.name] - Erster Inventargegenstand: [r: item1]
Code: Select all
[h: status = input(
"tab0 | Waffe || TAB",
"waffe.name|Bitte eingeben|Name|TEXT ##
waffe.typ|Bitte eingeben|Typ|TEXT ##
waffe.bonus|Bitte eingeben|Schadensbonus|TEXT",
"tab1 | Inventar || TAB|SELECT=TRUE",
"item1|Bitte eingeben|Gegenstand 1|TEXT ##
item2|Bitte eingeben|Gegenstand 2|TEXT ##
item3|Bitte eingeben|Gegenstand 3|TEXT"
)]
[h: abort(status)]
Inhalt der Variable tab0 (Waffentab): [r: tab0]