Code: Select all
[h: listActionTypes = "2. Traits, 3. Standard Actions, 4. Move Actions, 5. Minor Actions, 6. Triggered Actions"]
[h: listDamageLevel = "Minion, Very Low, Low, Normal, High, Very High, Extreme"]
[h: listUsage = "At-Will, Recharge, Encounter, Not Applicable"]
[h: x = input(
"MacroName | NewPower| Power Name || WIDTH=20",
"TargetRange | (M1) | Targets-Aura-Etc || WIDTH=10",
"ActionType | " + listActionTypes + " | Action Type | LIST | VALUE=STRING SELECT=1",
"SortOrder | 1 | Sort order || WIDTH=2",
"Usage | " + listUsage + " | Usage | LIST | VALUE=STRING SELECT=0",
"NumberOfTargets | Single-Target, Multi-Target, No Targets | Number of Targets | LIST | VALUE=STRING SELECT=0",
"AttackRollRequired | 1 | Attack roll? | CHECK | ",
"DamageRollRequired | 1 | Damage roll? | CHECK | ",
"RequirementIncluded | 0 | Requirement line? | CHECK | ",
"PreAttackEffectIncluded | 0 | Pre-attack effect? | CHECK | ",
"MissEffectIncluded | 0 | Miss effect? | CHECK | ",
"AftereffectIncluded | 0 | After-save effect? | CHECK | ",
"PostAttackEffectIncluded | 0 | Post-attack effect? | CHECK | ",
"SpecialEffectIncluded | 0 | Special effect? | CHECK | "
)]
[h: abort(x)]
[h: DefenseTargeted='AC']
[h: Enhancement=0]
[h: DamageLevel="Normal"]
[h: DefaultDamageLevel=3]
[h, if(getProperty("Role")=="Brute"): DefaultDamageLevel=DefaultDamageLevel+1]
[h, if(Usage=="Recharge"): DefaultDamageLevel=DefaultDamageLevel+1]
[h, if(Usage=="Encounter"): DefaultDamageLevel=DefaultDamageLevel+2]
[h, if(NumberOfTargets=="Multi-Target"): DefaultDamageLevel=DefaultDamageLevel-1]
[h, if(getProperty("SubType")=="Minion"): DefaultDamageLevel=0]
[h: RechargeTargetInputString=if(Usage=="Recharge",encode("RechargeTarget | 2, 3, 4, 5, 6 | Recharge Target | LIST | VALUE=STRING SELECT=3"),"")]
[h: DamageRollInputString=if(DamageRollRequired==1,encode("DamageLevel | " + listDamageLevel + " | Damage Level | LIST | VALUE=STRING SELECT=" + DefaultDamageLevel),"")]
[h: EnhancementInputString=if(DamageRollRequired==1,encode("Enhancement | 0 | Extra damage on crit? | CHECK | "),"")]
[h: ExtraAttackBonusInputString=if(AttackRollRequired==1,encode("ExtraAttackBonus | 0 | Extra attack bonus | | WIDTH=2"),"")]
[h: JustEffectInputString=if(AttackRollRequired==0,encode("JustEffect | . | Effect line | | WIDTH=50"),"")]
[h: DefenseInputString=if(AttackRollRequired==1,encode("DefenseTargeted | AC, Fortitude, Reflex, Will | Defense targeted | LIST | VALUE=STRING SELECT=0"),"")]
[h: HitStringInputString=if(AttackRollRequired==1&&DamageRollRequired==1,encode("HitStringWithDamage | damage | Hit line after damage roll | | WIDTH=50"),if(AttackRollRequired==1&&DamageRollRequired==0,encode("HitStringNoDamage | . | Hit line | | WIDTH=50"),if(AttackRollRequired==0&&DamageRollRequired==1,encode("EffectStringNoAttack | damage | Effect line after damage roll | | WIDTH=50"),"")))]
[h: RequirementInputString=if(RequirementIncluded==1,encode("Requirement | . | Requirement | | WIDTH=50"),"")]
[h: TriggerInputString=if(ActionType=="6. Triggered Actions",encode("Trigger | . | Trigger | | WIDTH=50"),"")]
[h: PreAttackEffectInputString=if(PreAttackEffectIncluded==1,encode("PreAttackEffect | . | Pre-Attack Effect | | WIDTH=50"),"")]
[h: MissEffectInputString=if(MissEffectIncluded==1,encode("MissEffect | . | Miss Effect | | WIDTH=50"),"")]
[h: AftereffectInputString=if(AftereffectIncluded==1,encode("Aftereffect | . | Aftereffect | | WIDTH=50"),"")]
[h: PostAttackEffectInputString=if(PostAttackEffectIncluded==1,encode("PostAttackEffect | . | Post-attack effect | | WIDTH=50"),"")]
[h: SpecialEffectInputString=if(SpecialEffectIncluded==1,encode("SpecialEffect | . | Special Effect | | WIDTH=50"),"")]
[h: x = input(
decode(RechargeTargetInputString),
decode(RequirementInputString),
decode(TriggerInputString),
decode(PreAttackEffectInputString),
decode(ExtraAttackBonusInputString),
decode(DefenseInputString),
decode(DamageRollInputString),
decode(EnhancementInputString),
decode(HitStringInputString),
decode(MissEffectInputString),
decode(AftereffectInputString),
decode(PostAttackEffectInputString),
decode(SpecialEffectInputString),
decode(JustEffectInputString)
)]
[h: abort(x)]
[h, switch(DamageLevel), code:
case "Minion": {
[h: NumDice=0]
[h: DieSize="MinionDamage"]
[h: DamageBonus="MinionDamage"]
[h: Enh=1]
[h: CritDamageDie="MinionDamage"]
};
case "Very Low": {
[h: NumDice="NumDice50"]
[h: DieSize="DamageDie50"]
[h: DamageBonus="DamageBonus50"]
[h: Enh=Enhancement]
[h: CritDamageDie="DamageDie50"]
};
case "Low": {
[h: NumDice="NumDice75"]
[h: DieSize="DamageDie75"]
[h: DamageBonus="DamageBonus75"]
[h: Enh=Enhancement]
[h: CritDamageDie="DamageDie75"]
};
case "Normal": {
[h: NumDice="NumDice100"]
[h: DieSize="DamageDie100"]
[h: DamageBonus="DamageBonus100"]
[h: Enh=Enhancement]
[h: CritDamageDie="DamageDie100"]
};
case "High": {
[h: NumDice="NumDice125"]
[h: DieSize="DamageDie125"]
[h: DamageBonus="DamageBonus125"]
[h: Enh=Enhancement]
[h: CritDamageDie="DamageDie125"]
};
case "Very High": {
[h: NumDice="NumDice150"]
[h: DieSize="DamageDie150"]
[h: DamageBonus="DamageBonus150"]
[h: Enh=Enhancement*2]
[h: CritDamageDie="DamageDie150"]
};
case "Extreme": {
[h: NumDice="NumDice175"]
[h: DieSize="DamageDie175"]
[h: DamageBonus="DamageBonus175"]
[h: Enh=Enhancement*2]
[h: CritDamageDie="DamageDie175"]
}
]
[h: AttackBonus=if(DefenseTargeted=='AC','DefaultAttackBonusVsAC','DefaultAttackBonusVsNAD')]
[h: MyCommand=""]
[h: MyCommand=MyCommand+encode("<b>" + MacroName + "</b> " + TargetRange + "<br>\\n")]
[h, if(RequirementIncluded==1): MyCommand=MyCommand+encode("<i>Requirement:</i> "+Requirement+"<br>\\n")]
[h, if(ActionType=="6. Triggered Actions"): MyCommand=MyCommand+encode("<i>Trigger:</i> "+Trigger+"<br>\\n")]
[h, if(PreAttackEffectIncluded==1): MyCommand=MyCommand+encode("<i>Effect:</i> "+PreAttackEffect+"<br>\\n")]
[h, if(AttackRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode("[h: AttackBonus=" + AttackBonus + " + " + ExtraAttackBonus + "]\\n")]
[h: MyCommand=MyCommand+encode("[h: Defense='"+DefenseTargeted+"']\\n")]
[h: MyCommand=MyCommand+encode("[h: d20roll=d20]\\n")]
[h: MyCommand=MyCommand+encode("[h: Enh="+Enh+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: CritDamageDie="+CritDamageDie+"]\\n\\n")]
[h: MyCommand=MyCommand+encode("[h, if(CritDamageDie > 0), CODE:\\n { [CritBonus=roll(Enh,CritDamageDie)] }; \\n { [CritBonus=0] }\\n ]\\n\\n")]
[h: MyCommand=MyCommand+encode("[h: AttackRoll=d20roll+AttackBonus]\\n")]
}
]
[h, if(DamageRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode("[h: DamageString='"+HitStringWithDamage+"']\\n")]
[h: MyCommand=MyCommand+encode("[h: NumDice="+NumDice+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: DamageDie="+DieSize+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: DamageBonus="+DamageBonus+"]\\n\\n")]
[h: MyCommand=MyCommand+encode("[h: DamageRoll=roll(NumDice,DamageDie)]\\n")]
[h: MyCommand=MyCommand+encode("[h: NumDice="+NumDice+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: MaxDamage=NumDice*DamageDie+DamageBonus+CritBonus]\\n")]
[h: MyCommand=MyCommand+encode("[h: RegularDamage=DamageRoll+DamageBonus]\\n\\n")]
}
]
[h, if(NumberOfTargets=="Single-Target" && AttackRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode("<i>Attack:</i> [d20roll] + [AttackBonus] = <b>[AttackRoll]</b> versus [Defense]<br>\\n")]
[h, if(DamageRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode("[if(d20roll==20), CODE:\\n")]
[h: MyCommand=MyCommand+encode(" {<font color=red>--CRITICAL HIT--</font><br>\\n")]
[h: MyCommand=MyCommand+encode(" <i>Hit:</i> [NumDice*DamageDie] ([NumDice]d[DamageDie]) + [DamageBonus] + [CritBonus] = <b>[MaxDamage]</b> [DamageString]<br>\\n")]
[h: MyCommand=MyCommand+encode(" };\\n")]
[h: MyCommand=MyCommand+encode(" {<i>Hit:</i> [DamageRoll] ([NumDice]d[DamageDie]) + [DamageBonus] = <b>[RegularDamage]</b> [DamageString]<br>}\\n")]
[h: MyCommand=MyCommand+encode("]\\n")]
};
{[h: MyCommand=MyCommand+encode("<i>Hit:</i> "+HitStringNoDamage+"\\n")]
}
]
};{}
]
[h, if(NumberOfTargets=="Multi-Target" && AttackRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode("[h: x=input('NumberOfTargets|0|Number of targets')]\\n")]
[h: MyCommand=MyCommand+encode("[h: abort(x)]\\n\\n")]
[h: MyCommand=MyCommand+encode("Attacking [NumberOfTargets] [if(NumberOfTargets==1,'target','targets')].<br>\\n")]
[h: MyCommand=MyCommand+encode("[count(NumberOfTargets,'<br>'), CODE: {\\n")]
[h: MyCommand=MyCommand+encode(" [h: d20roll=d20]\\n")]
[h: MyCommand=MyCommand+encode(" [h: AttackRoll=d20roll+AttackBonus]\\n")]
[h: MyCommand=MyCommand+encode(" <i>Target [r:roll.count+1]:</i> [d20roll] + [AttackBonus] = <b>[AttackRoll]</b> versus [Defense]\\n")]
[h, if(DamageRollRequired==1), CODE: {
[h: MyCommand=MyCommand+encode(" [if(d20roll==20), CODE: {<font color=Red> --CRITICAL HIT--</font> [NumDice*DamageDie] ([NumDice]d[DamageDie]) + [DamageBonus] + [CritBonus] = <b>[MaxDamage]</b> [DamageString]};{} ]\\n")]
[h: MyCommand=MyCommand+encode(" }\\n")]
[h: MyCommand=MyCommand+encode("]<br><br>\\n")]
[h: MyCommand=MyCommand+encode("<i>Hit:</i> [DamageRoll] ([NumDice]d[DamageDie]) + [DamageBonus] = <b>[RegularDamage]</b> [DamageString]<br>\\n")]
};
{[h: MyCommand=MyCommand+encode("<i>Hit:</i> "+HitStringNoDamage+"\\n")]
}
]
}
]
[h, if(AttackRollRequired==0&&DamageRollRequired==1): MyCommand=MyCommand+encode("<i>Hit:</i> [DamageRoll] ([NumDice]d[DamageDie]) + [DamageBonus] = <b>[RegularDamage]</b> [DamageString]<br>}\\n")]
[h, if(MissEffectIncluded==1): MyCommand=MyCommand+encode("<i>Miss:</i> "+MissEffect+"<br>\\n")]
[h, if(AftereffectIncluded==1): MyCommand=MyCommand+encode("<i>Aftereffect:</i> "+Aftereffect+"<br>\\n")]
[h, if(PostAttackEffectIncluded==1): MyCommand=MyCommand+encode("<i>Effect:</i> "+PostAttackEffect+"<br>\\n")]
[h, if(SpecialEffectIncluded==1): MyCommand=MyCommand+encode("<i>Special:</i> "+SpecialEffect+"<br>\\n")]
[h, if(AttackRollRequired==0): MyCommand=MyCommand+encode("<i>Effect:</i> "+JustEffect+"<br>\\n")]
[h: FontColor="green"]
[h, if(Usage=="Encounter"), CODE: {
[h: EncountersArray=getProperty("EncounterPowersDeclared")]
[h: FirstEmptyEncounter=-1]
[h, for(i, 9, -1, -1), CODE:
{[h: PowerCheck=json.get(EncountersArray,i)]
[h, if(PowerCheck==0): EncounterPowerNumber=i]
}
]
[h: FontColor="red"]
[h: NewArray=json.set(EncountersArray, EncounterPowerNumber, 1)]
[h: setProperty("EncounterPowersDeclared", NewArray)]
[h: MyCommand=MyCommand+encode("[h: PowerNumber="+EncounterPowerNumber+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: PowersCharged=getProperty('EncounterPowersCharged')]\\n")]
[h: MyCommand=MyCommand+encode("[h: IsPowerAvailable=json.get(PowersCharged,PowerNumber)]\\n\\n")]
[h: MyCommand=MyCommand+encode("[h, if(IsPowerAvailable==0), CODE:\\n")]
[h: MyCommand=MyCommand+encode(" {[assert(1==0,add('This power has already been expended.'),0)]};\\n")]
[h: MyCommand=MyCommand+encode(" {[h: NewArray=json.set(PowersCharged,PowerNumber,0)]\\n")]
[h: MyCommand=MyCommand+encode(" [h: setProperty('EncounterPowersCharged', NewArray)]}]\\n")]
[h: MyCommand=MyCommand+encode("[h: setMacroProps(getMacroButtonIndex(), 'color=darkgray') ]")]
}
]
[h, if(Usage=="Recharge"), CODE: {
[h: RechargeArray=getProperty("RechargePowersDeclared")]
[h: FirstEmptyRecharge=-1]
[h, for(i, 9, -1, -1), CODE:
{[h: PowerCheck=json.get(RechargeArray,i)]
[h, if(PowerCheck==0): RechargePowerNumber=i]
}
]
[h: FontColor="purple"]
[h: NewArray=json.set(RechargeArray, RechargePowerNumber, 1)]
[h: setProperty("RechargePowersDeclared", NewArray)]
[h: MyCommand=MyCommand+encode("[h: RechargeTarget="+RechargeTarget+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: RechargeRoll=d6]\\n")]
[h: MyCommand=MyCommand+encode("[h: PowerNumber="+RechargePowerNumber+"]\\n")]
[h: MyCommand=MyCommand+encode("[h: PowersCharged=getProperty('RechargePowersCharged')]\\n")]
[h: MyCommand=MyCommand+encode("[h: IsPowerAvailable=json.get(PowersCharged,PowerNumber)]\\n\\n")]
[h: MyCommand=MyCommand+encode("[h, if(IsPowerAvailable==0 && RechargeRoll<RechargeTarget), CODE:\\n")]
[h: MyCommand=MyCommand+encode(" {[g: assert(1==0,add('Recharge roll = ', RechargeRoll, '. The power fails to recharge.'),0)]};\\n")]
[h: MyCommand=MyCommand+encode(" {[h: NewArray=json.set(PowersCharged,PowerNumber,0)]\\n")]
[h: MyCommand=MyCommand+encode(" [h: setProperty('RechargePowersCharged', NewArray)]}]\\n")]
[h: MyCommand=MyCommand+encode("[h: setMacroProps(getMacroButtonIndex(), 'color=gray') ]")]
}
]
[h, if(Usage=="Not Applicable"): FontColor="black"]
[h: MacroProps='{"autoexecute":1, "label":"'+MacroName+" "+TargetRange+'", "group":"'+ActionType+'", "sortBy":'+SortOrder+', "fontColor":"'+FontColor+'", "command":"'+decode(MyCommand)+'"}']
[h: createMacro(MacroProps)]